Антивирус Avira: ошибка "На этой странице произошла ошибка сценария"

На компьютере появляется окно:

На этой странице произошла ошибка сценария
Строка: 397
Символ:13
Ошибка: не удалось получить свойство "scrollTop" ссылки, значение которой не определено или является Null
Код: 0
URL: file:///C:ProgramData/Avira/Antivirus/IPM/IpmDocument.html
Вы хотите продолжить выполнение сценария на этой странице?
Да Нет

Проблема не в том, что появляется окно с ошибкой, а в том, что после того, как это окно закроешь, часть экрана перестаёт реагировать на клики мышки.

В интернете советы от "Удалить всё содержимое каталога C:\ProgramData\Avira\Antivirus\IPM и перезагрузить компьютер" до "Полностью переустановить Avira с использованием Registry Cleaner от Avira". Проблема в том, что через некоторое время эта ошибка появляется снова. Дело в том, что IpmDocument.html - это файлик с рекламой, которую время от времени показывает Avira. Соответственно, он подкачивается заново и, если в нём ошибка, то всё повторяется.

Поэтому я написал скрипт, который проверяет наличие этого файла и удаляет его. Кроме того, прибивает программу, которая запускает этот файл. Костыль, конечно, но, вроде бы, работает.

@ECHO OFF
SETLOCAL
REM Файл лога:
SET LOG=%~dp0\Avira.log
REM Поиск в запущенных процессах процесса, который отвечает за запуск рекламного объявления
REM и его прекращение
set filename=ipmgui.exe
REM if "%1" neq "" set filename=%1
for /f %%a in ('tasklist /nh /fi "imagename eq %filename%" ^| find /c "%filename%"') do set /a quantity=%%a
rem Если запущена 1 и более копий процесса
if %quantity% geq 1 goto ALREADY_RUN
DATE /t >> %LOG%
TIME /t >> %LOG%
echo No processes of %filename%! >> %LOG%
rem ... Вставьте сюда свои команды, когда процесс НЕ запущен ...
goto IPM
:ALREADY_RUN
DATE /t >> %LOG%
TIME /t >> %LOG%
echo Already run %quantity% processes of %filename% >> %LOG%
rem ... Вставьте сюда свои команды, когда процесс запущен ...
TASKKILL /F /IM ipmgui.exe
REM Поиск и удаление файла с рекламным объявлением
:IPM
IF EXIST C:\ProgramData\Avira\Antivirus\IPM\IpmDocument.html (
   ECHO File exist, deleted >> %LOG%
   DEL /Q /F C:\ProgramData\Avira\Antivirus\IPM\*.*
   ) ELSE (
   ECHO File not exist, well done >> %LOG%
   )
REM 25 числа каждого месяца удаляем файл лога, чтобы не рос бесконечно
SET DAY=%DATE:~0,2%
IF %DAY% == 25 (
   IF EXIST %LOG%.bak DEL %LOG%.bak
   REN %LOG% Avira.log.bak
   )
   
:END

Скрипт запускается планировщиком каждые полчаса. Расположение скрипта - произвольное, но обычно скрипты находятся в D:\programs\cmd. Старт - при запуске компьютера. Раз в полчаса на экране мелькает чёрное окно командной строки, но очень быстро, так что практически и не мешает.